#version 450
#extension GL_EXT_shader_explicit_arithmetic_types_int32 : require

#include "mul_mat_vec_base.glsl"

layout(local_size_x_id = 0, local_size_y = 1, local_size_z = 1) in;

FLOAT_TYPE temp[NUM_COLS][NUM_ROWS];

void calc_superblock(const uint a_offset, const uint b_offset, const uint itid, const uint i, const uint num_blocks_per_row, const uint first_row, const uint num_rows) {
    const uint y_idx = i * QUANT_K + 16 * itid;
    const uint nibble_shift = 4 * (itid & 1);
    const uint ib32 = itid / 2; // 0..7
    uint ibi = a_offset / QUANT_K + first_row * num_blocks_per_row + i;
    // Precompute db multiplication factors
    float db_vals[NUM_ROWS];
    [[unroll]] for (uint n = 0; n < num_rows; ++n) {
        const float d = float(data_a[ibi].d);
        const uint scale_raw = data_a[ibi].scales[ib32];
        const uint scale = (scale_raw >> nibble_shift) & 0xF;
        // Merge constant calculations d * (0.5 + scale) * 0.25 = d*0.125 + d*scale*0.25
        db_vals[n] = d * (0.125f + float(scale) * 0.25f);
        ibi += num_blocks_per_row;
    }
    ibi = a_offset / QUANT_K + first_row * num_blocks_per_row + i;
    [[unroll]] for (uint n = 0; n < num_rows; ++n) {
        // Preload grid and sign data for all l values
        vec4 grid0_vals[2], grid1_vals[2];
        uint sign_vals[2], sign7_vals[2];
        [[unroll]] for (uint l = 0; l < 2; ++l) {
            const uint qs = data_a[ibi].qs[2 * itid + l];
            sign_vals[l] = qs >> 9;
            sign7_vals[l] = bitCount(sign_vals[l]);
            const uvec2 grid_data = iq2xs_grid[qs & 511];
            grid0_vals[l] = vec4(unpack8(grid_data.x));
            grid1_vals[l] = vec4(unpack8(grid_data.y));
        }
        // Preload B data for all j columns (reduce repeated index calculations)
        [[unroll]] for (uint j = 0; j < NUM_COLS; ++j) {
            FLOAT_TYPE sum = FLOAT_TYPE(0.0);
            [[unroll]] for (uint l = 0; l < 2; ++l) {
                const uint sign = sign_vals[l];
                const uint sign7 = sign7_vals[l];
                const vec4 grid0 = grid0_vals[l];
                const vec4 grid1 = grid1_vals[l];
                // Precompute indices
                const uint b_idx = (j * p.batch_stride_b + b_offset + y_idx) / 4 + 2 * l;
                const vec4 b0 = vec4(data_b_v4[b_idx + 0]);
                const vec4 b4 = vec4(data_b_v4[b_idx + 1]);
                sum +=
                    fma(FLOAT_TYPE(b0.x), FLOAT_TYPE((sign &   1) != 0 ? -grid0.x : grid0.x),
                    fma(FLOAT_TYPE(b0.y), FLOAT_TYPE((sign &   2) != 0 ? -grid0.y : grid0.y),
                    fma(FLOAT_TYPE(b0.z), FLOAT_TYPE((sign &   4) != 0 ? -grid0.z : grid0.z),
                    fma(FLOAT_TYPE(b0.w), FLOAT_TYPE((sign &   8) != 0 ? -grid0.w : grid0.w),
                    fma(FLOAT_TYPE(b4.x), FLOAT_TYPE((sign &  16) != 0 ? -grid1.x : grid1.x),
                    fma(FLOAT_TYPE(b4.y), FLOAT_TYPE((sign &  32) != 0 ? -grid1.y : grid1.y),
                    fma(FLOAT_TYPE(b4.z), FLOAT_TYPE((sign &  64) != 0 ? -grid1.z : grid1.z),
                    fma(FLOAT_TYPE(b4.w), FLOAT_TYPE((sign7 &  1) != 0 ? -grid1.w : grid1.w),
                    FLOAT_TYPE(0.0)))))))));
            }
            temp[j][n] = fma(FLOAT_TYPE(db_vals[n]), sum, temp[j][n]);
        }
        ibi += num_blocks_per_row;
    }
}

void compute_outputs(const uint32_t first_row, const uint32_t num_rows) {
    uint a_offset, b_offset, d_offset;
    get_offsets(a_offset, b_offset, d_offset);

    const uint num_blocks_per_row = p.ncols / QUANT_K;

    // 16 threads are used to process each block
    const uint blocks_per_wg = gl_WorkGroupSize.x/16;
    const uint tid = gl_LocalInvocationID.x;
    const uint itid = tid % 16;  // 0...15
    const uint ix = tid / 16;

    [[unroll]] for (uint j = 0; j < NUM_COLS; ++j) {
        [[unroll]] for (uint i = 0; i < NUM_ROWS; ++i) {
            temp[j][i] = FLOAT_TYPE(0);
        }
    }

    [[unroll]] for (uint i = ix; i < num_blocks_per_row; i += blocks_per_wg)
        calc_superblock(a_offset, b_offset, itid, i, num_blocks_per_row, first_row, num_rows);

    reduce_result(temp, d_offset, first_row, num_rows, tid);
}

void main() {
    const uint first_row = NUM_ROWS * (gl_WorkGroupID.x + gl_NumWorkGroups.x * gl_WorkGroupID.z);

    init_iq_shmem(gl_WorkGroupSize);

    // do NUM_ROWS at a time, unless there aren't enough remaining rows
    if (first_row + NUM_ROWS <= p.stride_d) {
        compute_outputs(first_row, NUM_ROWS);
    } else {
        if (first_row >= p.stride_d) {
            return;
        }
        compute_outputs(first_row, p.stride_d - first_row);
    }
}
